Параметризованные заголовки полей СКД

Программирование - Практика программирования

24
Доработанный шаблон типового отчета, который это позволяет менять заголовки полей в зависимости от значений параметров.

Для чего это нужно?

Периодически возникают задачи построения отчетов, в которых нужно вывести какую-то информацию в отчете, в зависимости от установленных параметров. Чаще всего это дата формирования отчета и ответственный. Если с датой формирования и ответственным все понятно и просто - их можно просто вывести в колонтитулах табличного документа или же создать группировку в отчете с типом Дополнительная информация и вывести параметры как поля, то в случае, например вывода сравнительных данных продаж за произвольный период - не совсем понятно как переименовать колонку с показателем Продажи другого периода на что-то более говорящее, например Продажи за Март 2017.

Эта доработка Шаблона типового отчета как раз и помогает это сделать.

При чем можно, как взять уже готовый доработанный шаблон, так и просто интегрировать процедуры в свой отчет.

Как это выглядит для пользователя

Пользователь указывает в заголовках полей названия параметров отчета(именно имена параметров, а не их представления) начиная с символа "#" (решетка). При формировании отчета этот текст заменяется на значение параметра.

Что доработано

Процедура, которая изменяет исполняемую копию КомпоновщикаНастроекКомпоновкиДанных. Очень важно, предварительно сохранить настройки компоновщика перед их модификацией, затем, после формирования отчета их обратно восстановить. В противном случае, при первом же исполнении программа вам перепишет символы подстановки на их значения.

Процедура ДоработатьКомпоновщикПередВыводом() Экспорт
	// Моя вставка КрынецкийАА 08.04.17. Переименуем заголовки полей, начинающихся с маркера "#"
	
	// Сначала найдем поля
	МассивПолей = Новый Массив;
	СписокЭлементовСтруктуры = ТиповыеОтчеты.ПолучитьЭлементыСтруктуры(КомпоновщикНастроек);
	Для Каждого ЭлементСписка Из СписокЭлементовСтруктуры Цикл 
		Поля = ТиповыеОтчеты.ПолучитьВыбранныеПоля(ЭлементСписка.Значение.Выбор);
		
		Для Каждого ЭлементМассива Из Поля Цикл
			// Так же добавим родителей, т.е. Группы выбранных полей
			Если ТипЗнч(ЭлементМассива.Родитель) = Тип("ГруппаВыбранныхПолейКомпоновкиДанных") Тогда
				МассивПолей.Добавить(ЭлементМассива.Родитель);
			КонецЕсли;
			
			МассивПолей.Добавить(ЭлементМассива);
		КонецЦикла;
		
		// Добавим в массив параметрыВывода.Заголовок
		Параметр = ТиповыеОтчеты.ПолучитьПараметрВывода(ЭлементСписка.Значение, "Заголовок");
		Если ЗначениеЗаполнено(Параметр.Значение) Тогда
			МассивПолей.Добавить(Параметр);
		КонецЕсли;
		
	КонецЦикла;
	
	// Добавим в массив поля самого отчета
	Поля = ТиповыеОтчеты.ПолучитьВыбранныеПоля(КомпоновщикНастроек.Настройки.Выбор);
	
	Для Каждого ЭлементМассива Из Поля Цикл
		// Так же добавим родителей, т.е. Группы выбранных полей
		Если ТипЗнч(ЭлементМассива.Родитель) = Тип("ГруппаВыбранныхПолейКомпоновкиДанных") Тогда
			МассивПолей.Добавить(ЭлементМассива.Родитель);
		КонецЕсли;
		
		МассивПолей.Добавить(ЭлементМассива);
	КонецЦикла;
	
	Параметр = ТиповыеОтчеты.ПолучитьПараметрВывода(КомпоновщикНастроек, "Заголовок");
	Если ЗначениеЗаполнено(Параметр.Значение) Тогда
		МассивПолей.Добавить(Параметр);
	КонецЕсли;
	
	
	// Затем доработаем заголовки, содержащие маркер "#"
	Для Каждого ВыбранноеПоле Из МассивПолей Цикл
		
		Если ТипЗнч(ВыбранноеПоле) = Тип("ВыбранноеПолеКомпоновкиДанных") ИЛИ 
			ТипЗнч(ВыбранноеПоле) = Тип("ГруппаВыбранныхПолейКомпоновкиДанных") Тогда
				МассивСлов = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(ВыбранноеПоле.Заголовок, " ");
			ИначеЕсли ТипЗнч(ВыбранноеПоле) = Тип("ЗначениеПараметраНастроекКомпоновкиДанных") Тогда
				МассивСлов = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(ВыбранноеПоле.Значение, " ");
		КонецЕсли;
		
		Для Каждого Слово Из МассивСлов Цикл
			Если Лев(Слово, 1) = "#" Тогда
				Параметр = ТиповыеОтчеты.ПолучитьПараметр(КомпоновщикНастроек, СтрЗаменить(Слово, "#", ""));
				
				// Удалось найти параметр по имени
				Если Параметр <> Неопределено Тогда
					
					// Преобразуем тип значения параметра, чтобы с ним можно было работать
					Если ТипЗнч(Параметр.Значение) = Тип("СтандартнаяДатаНачала") Тогда
						НовоеСлово = Параметр.Значение.Дата;
					ИначеЕсли ТипЗнч(Параметр.Значение) = Тип("ПолеКомпоновкиДанных") Тогда
						ИмяПоля = СтрЗаменить(Параметр.Значение, "ПараметрыДанных.", "");
						ПараметрДанных = КомпоновщикНастроек.Настройки.ПараметрыДанных.Элементы.Найти(ИмяПоля);
						НовоеСлово = ПараметрДанных.Значение;
					Иначе
						НовоеСлово = Параметр.Значение;
					КонецЕсли;
							
					Если ТипЗнч(НовоеСлово) = Тип("Дата") ИЛИ ТипЗнч(НовоеСлово) = Тип("СтандартнаяДатаНачала") Тогда
						НовоеСлово = Формат(НовоеСлово, "ДЛФ=D");
					КонецЕсли;
					
					Если ТипЗнч(ВыбранноеПоле) = Тип("ВыбранноеПолеКомпоновкиДанных") ИЛИ 
						ТипЗнч(ВыбранноеПоле) = Тип("ГруппаВыбранныхПолейКомпоновкиДанных") Тогда
						ВыбранноеПоле.Заголовок = СтрЗаменить(ВыбранноеПоле.Заголовок, Слово, НовоеСлово);
					ИначеЕсли ТипЗнч(ВыбранноеПоле) = Тип("ЗначениеПараметраНастроекКомпоновкиДанных") Тогда
						ВыбранноеПоле.Значение = СтрЗаменить(ВыбранноеПоле.Значение, Слово, НовоеСлово);
					КонецЕсли;
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;
		
	КонецЦикла;
	
КонецПроцедуры
 

Примеры

Имеем в отчете параметр Дата остатков, необходимо в колонке остатки указать на какую дату они. На скриншоте это параметр ДатаОстатковНедодела и показатель Недодел, заголовок которого меняется

Тестировалось на платформе 8.2.19.130, 8.3.12 в 1С:УПП 1.3.111.

24

Скачать файлы

Наименование Файл Версия Размер
Шаблон типового отчета(м)
.erf 38,88Kb
21.09.18
2
.erf 38,88Kb 2 Скачать

См. также

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. zeegin 32 24.09.18 12:55 Сейчас в теме
ИМХО, создать макет с типом "Заголовок группировки" в разы проще и понятнее. И в тексте ячейки макета вывести значение по шаблону с параметром. Писать код вообще не нужно.

Я как раз это недавно делал для монитора, см

https://github.com/axioma-project/MonthEndClosingMonitor/issues/2
https://github.com/axioma-project/MonthEndClosingMonitor/commit/6e42ea379e9b2addedaa0b­6d4de57f19da1c1388
JohnyDeath; sansys; Yashazz; echo77; +4 Ответить
2. echo77 981 24.09.18 13:28 Сейчас в теме
(1) Согласен, предложенный вами вариант проще, но он жёсткий - т.е всегда будет выводится поле с параметром.
3. zeegin 32 24.09.18 14:31 Сейчас в теме
(2) Для указанного списка группировок - да, фиксированный. Все что не попало в простронство группировок будет выведено типовым образом.
Оставьте свое сообщение